投稿日 | : 2003/01/16(Thu) 13:49 |
投稿者 | : 花ちゃん |
Eメール | : |
URL | : |
タイトル | : Re: GIFファイルアニメーションを表示したいのですが。 |
サンプル下記のを使って下さい。
こちらはスクロールバーを非表示に設定しているので細工が不要です。
Option Explicit
'指定の項目のシステムカラーのRGB値を取得する(445)
Private Declare Function GetSysColor Lib "user32" _
(ByVal nIndex As Long) As Long
Private Const COLOR_BTNFACE = 15 'コマンドボタンの表面色(445)
Private Sub Command1_Click()
'プロジェクト→コンポーネント で Microsoft Internet Controls に
'チェックを入れて、WebBrowserコントロールをFormに貼り付けて下さい
'プロジェクト→参照設定で Microsoft HTML Object Library に
'チェックを入れておいて下さい。
WebBrowser1.Navigate "c:\VBRescu1\173\AN050.GIF"
DoEvents '無いとエラーが発生
Dim HtmDoc As HTMLDocument
Set HtmDoc = WebBrowser1.Document
Dim myRGB As Variant
'コマンドボタンの表面色を取得し、HTM形式の色コードに変換
myRGB = HtmColor(GetSysColor(COLOR_BTNFACE))
'バックカラーをFormの色に設定(WinXP と Win9x では違うので)
HtmDoc.bgColor = "#" & myRGB(0) & myRGB(1) & myRGB(2)
With HtmDoc.body.Style
'枠線を非表示に設定(スペースを指定すると凹型になる"
.border = "0"
'スクロールバーを非表示に設定
.overflow = "hidden"
'こちらでバックカラーを指定してもOK
'.backgroundColor = "#" & myRGB(0) & myRGB(1) & myRGB(2)
End With
Set HtmDoc = Nothing
End Sub
Private Function HtmColor(ByVal VBColor As Long) As Variant
'VBの色コードからHTMの色コードに変換
Dim R As String
Dim G As String
Dim B As String
R = Hex$(VBColor And vbRed)
G = Hex$((VBColor And vbGreen) \ &H100)
B = Hex$((VBColor And vbBlue) \ &H10000)
If Len(R) = 1 Then R = "0" & R
If Len(G) = 1 Then G = "0" & G
If Len(B) = 1 Then B = "0" & B
HtmColor = Array(R, G, B)
End Function