こんにちは。わからないことがあるので投稿してみました。
Win98 SecondEdition　で　VB6.0 SP5 を使っています。
こちらのホームページにある「GIFファイルのアニメーションをVBで表示」サンプルを参考にしてみた
のですが、
Dim doc As MSHTML.HTMLDocument
の部分で「ユーザー定義型の・・・」というエラーがでてしまいました。WebBrowserコントロールを
貼り付けただけでは駄目なのでしょうか？？
宜しくお願いします。

サンプルには書いてないようですが、
プロジェクトの参照設定で『Microsoft HTML Object Library』にチェックしてみて下さい。

サンプル下記のを使って下さい。
こちらはスクロールバーを非表示に設定しているので細工が不要です。

Option Explicit
'指定の項目のシステムカラーのＲＧＢ値を取得する(445)
Private Declare Function GetSysColor Lib "user32" _
    (ByVal nIndex As Long) As Long
Private Const COLOR_BTNFACE = 15            'コマンドボタンの表面色(445)

Private Sub Command1_Click()
    'プロジェクト→コンポーネント で  Microsoft Internet Controls に
    'チェックを入れて、WebBrowserコントロールをFormに貼り付けて下さい
    'プロジェクト→参照設定で Microsoft HTML Object Library に
    'チェックを入れておいて下さい。
    WebBrowser1.Navigate "c:\VBRescu1\173\AN050.GIF"
    DoEvents                        '無いとエラーが発生
    Dim HtmDoc As HTMLDocument
    Set HtmDoc = WebBrowser1.Document
    Dim myRGB As Variant
    'コマンドボタンの表面色を取得し、HTM形式の色コードに変換
    myRGB = HtmColor(GetSysColor(COLOR_BTNFACE))
    'バックカラーをFormの色に設定（WinXP と　Win9x では違うので)
    HtmDoc.bgColor = "#" & myRGB(0) & myRGB(1) & myRGB(2)
    
    With HtmDoc.body.Style
        '枠線を非表示に設定(スペースを指定すると凹型になる"
        .border = "0"
        'スクロールバーを非表示に設定
        .overflow = "hidden"
        'こちらでバックカラーを指定してもＯＫ
        '.backgroundColor = "#" & myRGB(0) & myRGB(1) & myRGB(2)
    End With
    Set HtmDoc = Nothing
End Sub

Private Function HtmColor(ByVal VBColor As Long) As Variant
'VBの色コードからHTMの色コードに変換
    Dim R As String
    Dim G As String
    Dim B As String
    R = Hex$(VBColor And vbRed)
    G = Hex$((VBColor And vbGreen) \ &H100)
    B = Hex$((VBColor And vbBlue) \ &H10000)
    If Len(R) = 1 Then R = "0" & R
    If Len(G) = 1 Then G = "0" & G
    If Len(B) = 1 Then B = "0" & B
    HtmColor = Array(R, G, B)
End Function

takkさん＞
レスありがとうございました。チェック入れたらできました。

花ちゃんさん＞
レスありがとうございました。新しいサンプルを掲示してくださってありがとうございます。スクロー
ルバーを表示したのも、非表示にしたのもやってみようと思います。
ありがとうございました。