VB6.0 からの文字列関数
 　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　玄関へお回り下さい。
VB6.0 からの文字列関数の使用例　　　　　　　　　(263)
　 Option Explicit　'SampleNo=263　WindowsXP VB6.0(SP5) 2003.03.08


Private Sub Command1_Click()
'Filter関数の使用例
　　Dim ItemCode As Variant
　　Dim ItemA　　As Variant
　　Dim i　　　　As Long
　　ItemCode = Array("A123", "B001", "A001", "C003", "A002", "B003", "A010")

　　'Filter(1次元配列の文字列,検索する文字列,[引数含有の有無],[比較のモード])

　　ItemA = Filter(ItemCode, "A", True, vbTextCompare)
　　For i = LBound(ItemA) To UBound(ItemA)
　　　　Debug.Print ItemA(i)
　　Next i

　　'結果 A123
　　'　　 A001
　　'　　 A002
　　'　　 A010
End Sub


Private Sub Command2_Click()
'FormatCurrency関数の使用例

　　'FormatCurrency(書式を変換する式,[小数点以下の表示桁数], _
　　　　　　　　[小数点の左側のゼロ表示],[負の値のかっこ表示],[桁区切り記号])

　　Debug.Print FormatCurrency(12300)

　　'結果　\12,300
End Sub


Private Sub Command3_Click()
'FormatDateTime関数の使用例

　　'FormatDateTime(書式を変換する日付式,[日付/時刻形式を表す定数])

　　Debug.Print FormatDateTime(Date, vbLongDate)

　　'結果　　2003年3月7日
End Sub


Private Sub Command4_Click()
'FormatNumber関数の使用例

　　'FormatNumber(書式を変換する式,[小数点以下の表示桁数], _
　　　　　　　　[小数点の左側のゼロ表示],[負の値のかっこ表示],[桁区切り記号])

　　Debug.Print FormatNumber(12300)
　　Debug.Print FormatNumber(-12300, 0, vbFalse, vbTrue, vbUseDefault)

　　'結果　12,300.00
　　'　　　(12,300)
End Sub


Private Sub Command5_Click()
'FormatPercent関数の使用例

　　'FormatPercent(書式を変換する式,[小数点以下の表示桁数], _
　　　　　　　　[小数点の左側のゼロ表示],[負の値のかっこ表示],[桁区切り記号])

　　Debug.Print FormatPercent(0.25, 1)

　　'結果　25.0%
End Sub


Private Sub Command6_Click()
'InStrRev関数の使用例
　　Dim myString As String

　　'InStrRev(検索元文字列, 検索文字, [開始位置], [比較のモード])

　　myString = "あいうえおあいうえお"
　　Debug.Print InStrRev(myString, "お", -1, vbTextCompare)

　　'結果　　　10
End Sub


Private Sub Command7_Click()
'Join関数の使用例
　　Dim AddDat(2) As String
　　AddDat(0) = "527-1234"　　　　　　　'Text1.Text
　　AddDat(1) = "滋賀県八日市市"　　　　'Text2.Text
　　AddDat(2) = "八日市ＰCサービス"　　'Text3.Text

　　'Join(結合する文字列を含む1次元配列, [文字列を区切るのに使用する文字])

　　Debug.Print Join(AddDat, ",")
　　Debug.Print Join(AddDat)

　　'結果　527-1234,滋賀県八日市市,八日市ＰＣサービス
　　'　　　527-1234 滋賀県八日市市 八日市ＰＣサービス
End Sub


Private Sub Command8_Click()
'MonthName関数の使用例

　　'MonthName(月を示す数値,[月名の省略有無])

　　Debug.Print MonthName(Month(Date), False)

　　'結果　　3月
End Sub


Private Sub Command9_Click()
'Replace関数の使用例
　　Dim myString As String

　　'Replace(置換する元の文字列,検索する文字列,置換する文字列, _
　　　　　　　　　　[検索開始位置],[置換する文字列数],[比較のモード])

　　myString = "527-1234,滋賀県八日市市,八日市ＰＣサービス"
　　Debug.Print Replace(myString, ",", vbTab)

　　'結果　　527-1234　　滋賀県八日市市　八日市ＰＣサービス
End Sub


Private Sub Command10_Click()
'Round関数の使用例

　　'Round(丸めを行う数式 ,[丸めを行う小数点以下の桁数])

　　Debug.Print Round(123.45, 1)
　　Debug.Print Round(123.55, 1)

　　'結果　 123.4
　　'　　　 123.6
End Sub


Private Sub Command11_Click()
'Split関数の使用例
　　Dim AddDat　 As Variant
　　Dim myString As String
　　Dim i　　　　As Long
　　myString = "527-1234,滋賀県八日市市,八日市ＰＣサービス"

　　'Split(文字列と区切り文字を含んだ文字列, _
　　　　　　　　　　[区切りを識別する文字],[配列の要素数],[比較のモード])

　　AddDat = Split(myString, ",")
　　For i = LBound(AddDat) To UBound(AddDat)
　　　　Debug.Print AddDat(i)
　　Next i

　　'結果　527-1234
　　'　　　滋賀県八日市市
　　'　　　八日市PCサービス
End Sub


Private Sub Command12_Click()
'StrReverse関数の使用例

　　'StrReverse(文字の並びを逆にする文字列)

　　Debug.Print StrReverse("あいうえお")

　　'結果　　おえういあ
End Sub


Private Sub Command13_Click()
'WeekdayName関数の使用例

　　'WeekdayName(曜日を示す数値,[曜日名の省略の有無], [曜日の最初の日])

　　Debug.Print WeekdayName(Weekday(Date))

　　'結果　金曜日
End Sub
ヘルプには使用例が載っていないので、私の覚えとして、簡単な使用例を作って見ました。
詳しくはヘルプを見て、ご自分でコードを試して見て下さい。








2003/03/08