テキストファイル内で、行の先頭の文字列「ｘｘｘ」を含んでいる行だけを削除したいのですが
色々調べてもどうしても分かりませんでした。

それと、このテキストファイル内の行数が30万行くらいあるので、
途中で1000行とかで区切って読み込んだ方がいいのでしょうか。
どうかよろしくお願いします。

オーソドックスな方法なら下記のようになりますが、３０万行となると相当時間がかかる
ので、早くするには工夫が必要になってきます。
因みに１行当りの文字数はどの位・全体のファイルサイズは ＊＊MB

Private Sub Command1_Click()
    Dim TxtLine   As String
    Dim MyString  As String
    Dim lngFileNo As Long
    lngFileNo = FreeFile
    Open "c:\sampl.txt" For Input As #lngFileNo
    Do Until EOF(lngFileNo)
        Line Input #lngFileNo, TxtLine
        If InStr(TxtLine, "ｘｘｘ") <> 1 Then
            MyString = MyString & TxtLine & vbCrLf
        End If
    Loop
    Close #lngFileNo
        
    '保存処理
    lngFileNo = FreeFile
    Open "c:\sample1.txt" For Binary Access Write As #lngFileNo
    Put #lngFileNo, , MyString
    Close #lngFileNo
End Sub

おはようございます。
レスありがとうございます。
このプログラムは社内のデータを纏めるだけなので、
早さに関しては時間かかってもいいと言われました^^;
それと、1行の文字数は空白も含めて80文字固定になっていて、
全体のファイルサイズはテキストファイルで27.3MBです。

行頭が「×××」となっているならば
下記のような方法もとれますね。

Private Sub Command1_Click()
    Dim fnoR   As integer
    Dim fnoW   As integer
    Dim ReadLine As String

    fnoR = FreeFile
    Open "c:\sampl.txt" For Input As #fnoR
    fnoW = FreeFile
    Open "c:\sampl_rslt.txt" For Output As #fnoW

    Do Until EOF(fnoR)
        Line Input #fnoR, ReadLine
        If Left$(ReadLine,3) <> "×××" Then
            Print #fnoW, ReadLine
        End If
    Loop

    Close #fnoR
    Close #fnoW
End Sub