Printerオブジェクトで、印刷可能領域は ScaleHeight と ScaleWidth で取得できるのですが、その上余白、左余白を取得したいと思っています。
ScaleTop、ScaleLeft が何も指定しなければ「0」になると思うのですが、その「ScaleLeft=0,ScaleHeight=0」の位置が用紙のどこから始まるのかがプリンタによってまちまちで思うような位置に印字出来なくて困っています。
どなたか教えて下さい。

たしか、以前同じ質問されていたですよね！
レスがなかったので、気にとめていたかいがあって、つい最近発見しました。

GetDeviceCaps APIで取得できます。

ありがとうございます！
ＡＰＩは得意ではないのですが、やはり避けては通れない道なのですね（泣）。
頑張ります。

下記を試して見て下さい。

Private Declare Function GetDeviceCaps Lib "gdi32" _
    (ByVal hdc As Long, ByVal nIndex As Long) As Long
                                
Private Const PHYSICALHEIGHT = 111  
Private Const PHYSICALWIDTH = 110  
Private Const PHYSICALOFFSETX = 112
Private Const PHYSICALOFFSETY = 113


Private Sub Command1_Click()
    Dim LeftMargin As Long
    Dim TopMargin  As Long
    Dim PhysHeight As Long
    Dim PhysWidth  As Long
    
    LeftMargin = (GetDeviceCaps(Printer.hdc, PHYSICALOFFSETX) _
                    * Printer.TwipsPerPixelX / 56.7)
    TopMargin = (GetDeviceCaps(Printer.hdc, PHYSICALOFFSETY) _
                    * Printer.TwipsPerPixelY / 56.7)
    PhysWidth = (GetDeviceCaps(Printer.hdc, PHYSICALWIDTH) _
                    * Printer.TwipsPerPixelX / 56.7)
    PhysHeight = (GetDeviceCaps(Printer.hdc, PHYSICALHEIGHT) _
                    * Printer.TwipsPerPixelY / 56.7)
    
    Label1.Caption = "プリンター用紙印刷余白(左)　：   " & LeftMargin & " mm"
    Label2.Caption = "プリンター用紙印刷余白(上)　：   " & TopMargin & " mm"
    Label3.Caption = "プリンター用紙サイズ(幅)  　： " & PhysWidth & " mm"
    Label4.Caption = "プリンター用紙サイズ(高さ)　： " & PhysHeight & " mm"
End Sub

花ちゃんさん、ありがとうございます。
サンプルコードまで・・・
これからも頑張りますのでよろしくお願いします。