何時も参考にさせていただいています。ありがとうございます。

「HTMLファイルをダウンロードする」 にて拡張子ｈｔｍｌ、ｈｔｍは
上手くダウンロード出来ていますが下記の様なファイルは
拡張子が違うからかエラーになってしまいます。
ダウンロードするにはどうしたら良いかご指導いただけないでしょうか。

"http://oh2w.kolumbus.com/cgi-bin/qin.sh"

> "http://oh2w.kolumbus.com/cgi-bin/qin.sh"

上記はどのようなファイルなのでしょうか？　表示しないのですが？

花ちゃんさん、何時もありがとうございます。

> > "http://oh2w.kolumbus.com/cgi-bin/qin.sh"
> 上記はどのようなファイルなのでしょうか？　表示しないのですが？

上記は検索結果なので
下記の検索フォームにて「Search string 」に「 S92UN 」 と入れて
他はデフォルトのまま「SEARCH」を押して見て下さい。　
http://oh2w.kolumbus.com/dxs/qin.html

結果が表示されＩＥの「ファイル」「名前を付けて保存」ではＯＫですが
「HTMLファイルをダウンロード」ではエラーが戻って来ます。

実はこの検索フォームへのSubmit方法を「Q&A掲示板２」に質問しています。
まだ上手く出来ていませんが．．．。

http://oh2w.kolumbus.com/cgi-bin/qin.sh このアドレスで直接表示しない以上
DLは無理じゃないでしょうか？

> http://oh2w.kolumbus.com/cgi-bin/qin.sh このアドレスで直接表示しない以上
> DLは無理じゃないでしょうか？

花ちゃんさん、お手数をお掛けしました。ありがとうございました。
魔界の仮面弁士 さんのフォローでダウンロードの件は上手く行きました。

> 下記の検索フォームにて「Search string 」に「 S92UN 」 と入れて
> 他はデフォルトのまま「SEARCH」を押して見て下さい。　
> http://oh2w.kolumbus.com/dxs/qin.html

であれば、XMLHTTP(ServerXMLHTTP)オブジェクトを使って、例えばこんな感じで。

    Dim objXMLHTTP As Object
    
    Set objXMLHTTP = CreateObject("Microsoft.XMLHTTP")
'    Set objXMLHTTP = CreateObject("Msxml2.XMLHTTP")
'    Set objXMLHTTP = CreateObject("Msxml2.XMLHTTP.2.6")
'    Set objXMLHTTP = CreateObject("Msxml2.XMLHTTP.3.0")
'    Set objXMLHTTP = CreateObject("Msxml2.XMLHTTP.4.0")
    
    objXMLHTTP.Open "POST", "http://oh2w.kolumbus.com/cgi-bin/qin.sh", False
    objXMLHTTP.Send "dxcall=S92UN&Search+Target=dxcolumn&year=2003&band=ALL&mode=ALL&spots=25&Submit%21=SEARCH"

    If objXMLHTTP.Status >= 400 Then
        'エラー
        MsgBox objXMLHTTP.StatusText, vbExclamation, "応答コード: " & CStr(objXMLHTTP.Status)
        Set objXMLHTTP = Nothing
        Exit Sub
    End If

'    Debug.Print objXMLHTTP.responseText

    '受信内容をStreamオブジェクト経由でファイル出力
    With CreateObject("ADODB.Stream")
        .Open
        .Type = 1   '1=adTypeBinary
        .Write objXMLHTTP.responseBody
        .SaveToFile "C:\qin.sh", 2  '2=adSaveCreateOverWrite
        .Close
    End With

    MsgBox "保存完了", vbInformation, "C:\qin.sh"
    Set objXMLHTTP = Nothing

先のページを、InternetExplorerオブジェクト/WebBrowserコントロールに表示させるコードです。

    Dim objIE As Object
    Dim URL As String
    Dim PostData() As Byte

    Set objIE = CreateObject("InternetExplorer.Application")
    objIE.Visible = True
    
    URL = "http://oh2w.kolumbus.com/cgi-bin/qin.sh"
    PostData = StrConv("dxcall=S92UN&Search+Target=dxcolumn&year=2003&band=ALL&mode=ALL&spots=25&Submit%21=SEARCH", vbFromUnicode)
    
    objIE.Navigate2 URL, PostData:=PostData

魔界の仮面弁士 さん、何時もありがとうございます。

> であれば、XMLHTTP(ServerXMLHTTP)オブジェクトを使って、例えばこんな感じで。

一発で成功です。ありがとうございます。

以前に「Q&A掲示板２」か「超初心者専用Q&A掲示板」で 魔界の仮面弁士 さんに
Ｓｕｂｍｉｔに付いてサンプルを教えていただきました。
その時は全て　HTMLInputTextElement　で今も上手く動作しています。
今　「Q&A掲示板２」に、今回の質問の「検索ページ」へのＳｕｂｍｉｔの
質問をさせていただいています。前回には無かったＳｅｌｅｃｔと言うことで
HTMLSelectElement　に変更したりして、あれこれ試していますが　
まだ上手く行っていません。　
厚かましいお願いなのですがご指導いただけたら幸いです。