初めまして

さっそく質問なんですが、クラスモジュールからフォームにcallしたいのですが
どう書けばいいのか分かりません。

-----クラスモジュール(Class1)------
Sub aaa()
　　Call From1.ccc          ←？？？？？
End Sub

-----フォーム(Form1)-----
Dim Mo as New Class1

Sub bbb()
    Call Mo.aaa
End Sub

Sub ccc()
    Msgbox "成功"
End Sub


#Msgboxを表示させたいのですが どのように書いたらよいのか教えてください
お願いします。

'* フォームモジュール (Form1)
Option Explicit
Private Mo As New Class1
Private Sub Form_Load()
    Set Mo.wForm = Me
    Call Mo.aaa
End Sub
Public Sub ccc()
    MsgBox "成功"
End Sub

'* クラスモジュール (Class1)
Option Explicit
Public wForm As Form1
Public Sub aaa()
    Call wForm.ccc
End Sub

こんな感じ？
でも、普通こんなやり方はしないと思いますけど。

> さっそく質問なんですが、クラスモジュールからフォームにcallしたいのですが

そういうときはイベントを使いましょう。Event、RaiseEvent、WithEventsキーワードを使います。
例えば、下記のような方法があります。

> -----クラスモジュール(Class1)------

Public Enum ResultStatus
   Success
   Failure
End Enum

Public Event Finish(ByVal status As ResultStatus)

Sub aaa()
    RaiseEvent Finish(Success)
End Sub

> -----フォーム(Form1)-----

Private WithEvents Mo As Class1

Sub bbb()
    Call Mo.aaa
End Sub

Private Sub Form_Load()
    Set Mo = New Class1
End Sub

Private Sub Mo_Finish(ByVal status As ResultStatus)
    Select Case status
    Case Success
        MsgBox "成功"
    Case Failure
        MsgBox "失敗"
    Case Else
        'ありえません。
    End Select
End Sub

> そういうときはイベントを使いましょう。Event、RaiseEvent、WithEventsキーワードを使います。
> 例えば、下記のような方法があります。
>
> > -----クラスモジュール(Class1)------
>
> Public Enum ResultStatus
>    Success
>    Failure
> End Enum
>
> Public Event Finish(ByVal status As ResultStatus)
>
> Sub aaa()
>     RaiseEvent Finish(Success)
> End Sub
>  
> > -----フォーム(Form1)-----
>
> Private WithEvents Mo As Class1
>
> Sub bbb()
>     Call Mo.aaa
> End Sub
>
> Private Sub Form_Load()
>     Set Mo = New Class1
> End Sub
>
> Private Sub Mo_Finish(ByVal status As ResultStatus)
>     Select Case status
>     Case Success
>         MsgBox "成功"
>     Case Failure
>         MsgBox "失敗"
>     Case Else
>         'ありえません。
>     End Select
> End Sub


回答ありがとうございました。

追加質問なんですが、フォームで Call文を書かずにクラスモジュールからCallするというのは
無理なんでしょうか？

> 回答ありがとうございました。
>
> 追加質問なんですが、フォームで Call文を書かずにクラスモジュールからCallするというのは
> 無理なんでしょうか？

ムリではないと思います（やったことありませんが…）

ただ、クラスモジュールは本来 プログラムを部品化し再利用可能にするために使います。
なので普通はクラスモジュール内から特定のフォームオブジェクトなどにアクセスするようには作りません。
クラスモジュールの処理はなるべくクラスモジュール内で完結するように作り、
プロパティ、メソッド（と戻り値）、イベントなどを通してデータの受け渡しをします。

クラスモジュールから直接フォームを操作しないで下さい。
そういうプログラムの組み方ではクラスモジュールを使う意味がありません。

ま、どうしてもやりたいなら止めませんが……。
Form1のcccプロシージャをPublic指定にして下さい。

ソースをしっかり見てなかったみたいで
無茶な方法をしなくてもよかったみたいです(^^;)

ありがとうございました。m(__)m