初めまして

VB6.0でcsvをmdbにインポートは出来るのでしょうか？
現在はcsvをLine Inputで１行読み込み後、UPDATEでmdbに書き込んでおります。

一括で変換する方法はありますでしょうか？

こんにちは。

> VB6.0でcsvをmdbにインポートは出来るのでしょうか？
> 一括で変換する方法はありますでしょうか？

サンプルです。

Sub MdbInsertTEST()
    Dim strMDB  As String
    Dim strSQL  As String
    Dim strCSV  As String
    Dim strPath As String
    Dim TblName As String
    Dim adoConn As ADODB.Connection

    strMDB = "D:\TEST.mdb"      'MDB のFullPath
    strCSV = "TEST.CSV"         'CSV File 名
    strPath = "D:\TEST\"        'CSV File の Path
    TblName = "T_TEST"          'Table 名
    
    strSQL = "INSERT INTO " & TblName & " " & _
             "SELECT * FROM [" & strCSV & "] IN '" & strPath & "' " & _
             "'Text;HDR=YES'"
        
    Set adoConn = New ADODB.Connection
    
    With adoConn
        .Provider = "Microsoft.Jet.OLEDB.4.0"
        .ConnectionString = "Data Source=" & strMDB
        .Open
        .Execute strSQL
    End With

    adoConn.Close
    Set adoConn = Nothing
End Sub

YK様

早速のご返信ありがとうございます。

この場合、既存のテーブルに追加になるんですが、
もしよろしければstrSQL内で新規テーブルを作成して追加する方法があれば教えていただけないでしょうか？
（１行目がタイトル行になるとかいうのは無く、純粋に新規テーブルが出来、そこにインポートという流れです。）

こんにちは。
ご自分でも考えましょう。

    strSQL = "SELECT * INTO " & TblName & " " & _
             "FROM [" & strCSV & "] IN '" & strPath & "' " & _
             "'Text;HDR=YES'"
    　　　　　　　　　　^^^ヘッダーが無いときはNO
    Set adoConn = New ADODB.Connection
    With adoConn
        .Provider = "Microsoft.Jet.OLEDB.4.0"
        .ConnectionString = "Data Source=" & strMDB
        .Open
        On Error Resume Next
        .Execute "DROP TABLE " & TblName
        On Error GoTo 0
        .Execute strSQL
    End With