- 日時： 2007/07/15 15:16
- 名前： 花ちゃん
- ***********************************************************************************
* カテゴリー：[フォーム][][] *
* キーワード：ウィンドウ,Ｆｏｒｍ,キャプション,ControlBox,BorderStyle, *
***********************************************************************************
-----------------------------------------------------------------------------
Re：タイトルバーなしウインドウ 投稿者：ゆう(U) [1999/02/20(土)16：49分]
-----------------------------------------------------------------------------
タスクバーにアイコンとキャプションを残したままタイトルバーを
外す方法は、APIを使用することで出来ますよ。
Call sTitleReleace(Me)で付けたり外したり・・・
ゆー太郎さんに教わった方法です
※関数にアレンジは私がしてますけど・・・
標準モジュール
Private Declare Function GetWindowLong Lib "user32" _
Alias "GetWindowLongA" _
(ByVal hWnd As Long, _
ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" _
Alias "SetWindowLongA" _
(ByVal hWnd As Long, _
ByVal nIndex As Long, _
ByVal dwNewLong As Long) As Long
Private Declare Function SetWindowPos Lib "user32" _
(ByVal hWnd As Long, _
ByVal hWndInsertAfter As Long, _
ByVal X As Long, ByVal Y As Long, _
ByVal cx As Long, ByVal cy As Long, _
ByVal wFlags As Long) As Long
'==========================================================
'タイトルバーを付ける・外す sTitleReleace
'==========================================================
' Call sTitleReleace(myForm)
' 引数 myForm ：フォーム
'----------------------------------------------------------
Public Sub sTitleReleace(ByRef myForm As Form)
Const GWL_STYLE = (-16&)
Const SWP_NOSIZE = &H1&
Const SWP_NOMOVE = &H2&
Const SWP_NOZORDER = &H4&
Const SWP_FRAMECHANGED = &H20&
Const SWP_DRAWFRAME = SWP_FRAMECHANGED
Const WS_CAPTION = &HC00000
Dim Result As Long
With myForm
Result = GetWindowLong(.hWnd, GWL_STYLE)
Result = Result Xor WS_CAPTION
Result = SetWindowLong(.hWnd, GWL_STYLE, Result)
Result = SetWindowPos(.hWnd, 0&, 0&, 0&, 0&, 0&, _
SWP_DRAWFRAME Or _
SWP_NOZORDER Or _
SWP_NOMOVE Or _
SWP_NOSIZE)
End With
End Sub
Private Sub Form_Load()
Call sTitleReleace(Me)
End Sub
※花ちゃん(さん)へ
逆引きへ載せておくといいかも・・・
|
タイトルバーなしウインドウ(VB6.0)