VBレスキュー(花ちゃん) - VBレスキュー(花ちゃん)の投稿サンプル用掲示板

　　　　　サンプル投稿用掲示板　　 VB2005 ～用トップページ　　 VB6.0 用トップページ

リストボックスで右クリック(VB6.0) ( No.0 ) 　[親スレッドへ]

日時： 2007/07/16 10:08
名前： 花ちゃん: ***********************************************************************************
* カテゴリー：[リストボックス][マウス][]                                          *
* キーワード：選択状態,ListBox,,,,                                                *
***********************************************************************************

元質問：リストボックスで右クリック - まい 2003/09/06-04:36 No.5755

リストボックスで右クリックをしたときに、リストボックスの内容を選択するようにしたいのですが、うまくいきません。　
リストボックスの内容を左クリックした時は青く反転して選択できるように、右クリックで同じことをしたいのです。

-----------------------------------------------------------------------
Re: リストボックスで右クリック - 花ちゃん  2003/09/06-09:26 No.5757
-----------------------------------------------------------------------
こう言う事でしょうか？

Option Explicit

Private Declare Function LBItemFromPt Lib "comctl32" _
    (ByVal hLB As Long, ByVal x As Long, ByVal y As Long, _
     ByVal bAutoScroll As Long) As Long

Private Type POINTAPI
    x As Long
    y As Long
End Type

Private Declare Function GetCursorPos Lib "user32" _
    (lpPoint As POINTAPI) As Long

Private Sub List1_MouseDown(Button As Integer, _
                             Shift As Integer, x As Single, y As Single)
    If Button = vbRightButton Then
        Dim MPos     As POINTAPI
        Dim LstIndex As Long
        GetCursorPos MPos
        LstIndex = LBItemFromPt(List1.hWnd, MPos.x, MPos.y, False)
        If LstIndex <> -1 Then
            List1.Selected(LstIndex) = True
            'Debug.Print List1.Text
        End If
    End If
End Sub