投稿日	： 2007/05/07(Mon) 15:40
投稿者	： 魔界の仮面弁士
Ｅメール	：
ＵＲＬ	：
タイトル	： Re: データグリッドのソート

> 表示されたデータをソートすることは出来ないのでしょうか？

DataGrid に表示させている Recordset オブジェクトの、Sort プロパティを使うとか。


=== 簡易コード ===

Private Sub DataGrid1_HeadClick(ByVal ColIndex As Integer)
    rs.Sort = DataGrid1.Columns(ColIndex).DataField
End Sub



=== 少しだけ汎用化 ===

Private Sub DataGrid1_HeadClick(ByVal ColIndex As Integer)
    Call SortDataGridByColumn(DataGrid1, ColIndex)
End Sub

Public Sub SortDataGridByColumn(ByVal dg As MSDataGridLib.DataGrid, ByVal ColIndex As Integer)
    Dim DataSource As Object
    Set DataSource = dg.DataSource
    Dim RS As ADODB.Recordset
    If DataSource Is Nothing Then
        '未設定
        Set RS = Nothing
    ElseIf TypeOf DataSource Is ADODB.Recordset Then
        'Recordset
        Set RS = DataSource
    ElseIf dg.DataMember = "" Then
        'ADODC
        Set RS = DataSource.Recordset
    Else
        'DataEnvironment
        Set RS = DataSource.Recordsets(dg.DataMember)
    End If

    If Not RS Is Nothing Then
        Dim bmk As Variant
        If RS.Supports(adBookmark) Then
            bmk = dg.Bookmark
        Else
            bmk = Empty
        End If
        RS.Sort = dg.Columns(ColIndex).DataField
        If Not IsEmpty(bmk) Then
            dg.Bookmark = bmk
        End If
    End If
End Sub

★ - データグリッドのソート - こう 05/07-15:20No.9098
• Re: データグリッドのソート - 魔界の仮面弁士 05/07-15:40 No.9100
  • Re^2: データグリッドのソート - こう 05/07-17:04 No.9104
• Re: データグリッドのソート - シュウ 05/07-15:57 No.9102
  • Re^2: データグリッドのソート - こう 05/07-17:05 No.9105
  • Re^2: データグリッドのソート - 魔界の仮面弁士 05/07-23:15 No.9108
    • Re^3: データグリッドのソート - シュウ 05/08-11:09 No.9111