投稿日	： 2003/11/27(Thu) 21:58
投稿者	： 魔界の仮面弁士
Ｅメール	：
ＵＲＬ	：
タイトル	： Re: ファイルを読めなくするには。

> いろいろと試していると拡張子がdatのファイルでnotopadで開くとうまく??文字化けして中身が
notopad ではなく、
notepad ですね。(^^;

とりあえず、一案。

コンポーネントの追加:
  Microsoft DataGrid Control 6.0 (OLEDB)

参照設定:
  Microsoft ActiveX Data Object 2.5、またはそれ以上のバージョン

フォームに貼るコントロール:
  Text1 (TextBox)
  Command1 (CommandButton)
  Command2 (CommandButton)
  DataGrid1 (DataGrid)

ソース:
Option Explicit

Private WithEvents RS As ADODB.Recordset

Private Sub Command1_Click()
    '保存
    RS.Save Text1.Text, adPersistADTG
    MsgBox "保存しました。", vbInformation
End Sub

Private Sub Command2_Click()
    '読込
    Set RS = New ADODB.Recordset
    RS.Open Text1.Text
    Set DataGrid1.DataSource = RS
    MsgBox "読み込みました。", vbInformation
End Sub

Private Sub Form_Load()
    '項目の定義
    Set RS = New ADODB.Recordset
    RS.Fields.Append "名前", adBSTR
    RS.Fields.Append "メール", adBSTR
    RS.Fields.Append "生年月日", adDate
    RS.Open

    'コントロールの設定
    'このあたりは、デザイン時に設定してもOK
    DataGrid1.AllowAddNew = True
    DataGrid1.AllowDelete = True
    DataGrid1.AllowUpdate = True
    Text1.Text = "C:\名簿.ADTG"
    Command1.Caption = "保存"
    Command2.Caption = "読込"

    Set DataGrid1.DataSource = RS
End Sub

★ - ファイルを読めなくするには。 - やまちゃん 11/27-16:55No.6781
• Re: ファイルを読めなくするには。 - 花ちゃん 11/27-17:23 No.6782
  • Re^2: ファイルを読めなくするには。 - やまちゃん 11/27-17:35 No.6783
    • Re^3: ファイルを読めなくするには。 - 花ちゃん 11/27-18:40 No.6787
      • Re^4: ファイルを読めなくするには。 - ほし 11/27-19:28 No.6790
        • Re^5: ファイルを読めなくするには。 - やまちゃん 11/27-21:16 No.6793
          • Re^6: ファイルを読めなくするには。 - ほし 11/27-23:42 No.6795
      • Re^4: ファイルを読めなくするには。 - 花ちゃん 11/28-01:58 No.6796
• Re: ファイルを読めなくするには。 - 魔界の仮面弁士 11/27-21:58 No.6794
• アドバイスありがとうございました。 - やまちゃん 12/14-11:48 No.7142