投稿日	： 2003/02/19(Wed) 18:16
投稿者	： 花ちゃん
Ｅメール	：
ＵＲＬ	：
タイトル	： Re: ヘルプ表示

> SendKeysイベントで、表示する方法、または、別の表示方法がありましたら

HtmlHelp APIを使用すれば表示できます。

Option Explicit
'指定されたヘルプ ウィンドウでヘルプ トピックを開きます
Private Const HH_DISPLAY_TOPIC = &H0
'プログラムによって開かれたウィンドウをすべて閉じます
Private Const HH_CLOSE_ALL = &H12
'プログラム中から HTML Help の機能にアクセスできるようにする
Private Declare Function HTMLHelp Lib "hhctrl.ocx" _
    Alias "HtmlHelpA" (ByVal hwnd As Long, ByVal lpHelpFile As String, _
    ByVal wCommand As Long, ByVal dwData As Long) As Long
Private HelpFilePath As String      'ヘルプファイルのパス

Private Sub Form_Load()
    'ヘルプフィルの取得
    HelpFilePath = "c:\windows\Help\Htmhlp98.chm"
End Sub

Private Sub Command1_Click()
    'ヘルプファイルを開く
    HTMLHelp Me.hwnd, HelpFilePath, HH_DISPLAY_TOPIC, 0&
End Sub

Private Sub Command2_Click()
    'ヘルプファイルを閉じる
    HTMLHelp Me.hwnd, HelpFilePath, HH_CLOSE_ALL, 0&
End Sub

'Visual Basicの開発環境においてHTML Help APIを使用して
'HTML Helpファイルを表示したままプログラムを終了すると
'Visual Basic開発環境も終了（場合によってはアプリケーション
'エラーが発生）する不具合が報告されています。
'プログラムを終了する場合はHTML Helpファイルは閉じておいて
'下さい。

★ - ヘルプ表示 - mitu 02/19-17:12No.2801
• Re: ヘルプ表示 - 花ちゃん 02/19-18:16 No.2805