XPのエクスプローラの詳細表示で、
デジカメの撮影日が表示されるのですが、
あの日時は所得できないのでしょうか？

FindFirstFile を使って ftCreationTime を調べても、
更新日時しか所得出来ませんでした。
その他のAPIを使ったほうが良いのでしょうか？

winXP(sp1) , vb6(sp5)

MicroSoft Shell Controls And Automation を使用すれば可能です。
その他の項目も35項目ほど取得できます。

回答ありがとうございました。
使ったことないものなのですが、
方向性が分かったので、いろいろ勉強してみます。

撮影日だけならnobuさんが投稿されていたのですがファイルの更新日時と同じようです。

とりあえず下記を試して見て下さい。
Private Sub Command1_Click()
    Dim ObjShell   As Object
    Dim ObjFolder  As Object
    Dim myText     As String
    Dim i          As Long
    Dim FolderName As Variant
    FolderName = "c:\"
    Set ObjShell = CreateObject("Shell.Application")
    'ファイルが存在するフォルダを指定(※Variant型を指定して下さい）
    Set ObjFolder = ObjShell.NameSpace(FolderName)
    For i = 0 To 34
        myText = myText & i & "  " & ObjFolder.GetDetailsOf(, i) & "=" _
        & ObjFolder.GetDetailsOf(ObjFolder.ParseName("test.jpg"), i) & vbCrLf
    Next
    MsgBox myText
End Sub

※ 通常のようにString型の変数を使ったらだめだったので変数で使用できないと
　 思っていたら No.6443の投稿で教えて頂いたのを修正しておきます。

>     'ファイルが存在するフォルダを指定（変数ではだめです。）
>     Set objFolder = objShell.NameSpace("c:\")

いえ、変数でもOKだと思いますよ。
引数に指定できる物としては、例えば下記のような物があります。

　・Folderオブジェクト
  ・FolderItemオブジェクト(IsFolderプロパティがTrueを返す場合のみ)
  ・Variant型(内部形式は String, Long, Integerのいずれか)

この時、未対応のデータ型を指定してしまうと、NameSpaceメソッドから
Nothingが返される(またはエラーになる)ので、その点は注意が必要ですね。
(Script対応のオブジェクトという事もあり、基本的にはVariant型を指定する事になるでしょう)


なお、ここにString型の変数を指定したい場合は、
    Set objFolder = objShell.NameSpace(Path)
ではなく、
    Set objFolder = objShell.NameSpace((Path))
または
    Set objFolder = objShell.NameSpace(CVar(Path))
または、
    Dim V As Variant
    V = Path
    Set objFolder = objShell.NameSpace(V)
などとして、Variant型への変換を伴うように指定すればOKです。

フォローありがとうございます。
通常のようにString型で指定していたらだめだったので、深く考えずそのまま使用して
いましたが、Variant型にすればできたのですね、勉強になりました。

サンプルまで作っていただき本当にありがとうございました。
しかし、内部ではString型を使っているのに、
Variant型じゃないと受け付けないってのも面白いですね。
vbってホント奥が深いです。がんばります。